你好,游客 登录 注册 搜索
背景:
阅读新闻

Windows下MySQL自动备份的batch脚本

[日期:2017-08-24] 来源:Linux社区  作者:jim123 [字体: ]

在Unix系统环境中可以通过各种Unix shell结合cron任务实现对MySQL的自动备份,那在Windows下要如何实现呢,其实很简单只要写好自定义的batch脚本在结合taskschd.msc(任务计划程序),就可以实现,最近需要修改调优Windows环境下的MySQL就顺便写了一个使用mysqldump做逻辑备份的batch脚本,如下:

@echo off
::mysql_backup.bat
set hour=%time:~0,2%
if "%time:~0,1%"==" " set hour=0%time:~1,1%
set now=%Date:~0,4%%Date:~5,2%%Date:~8,2%%hour%%Time:~3,2%%Time:~6,2%
::主机ip
set host=127.0.0.1
::端口
set port=3306
::用户
set username=root
::密码
set password=youpassword
::要备份数据库的名字,如果有多个库请用空格分隔
set databasename=database1 database2
:: MySQL Bin 目录
:: 如果在安装配置时添加 MySQL Bin 目录到了环境变量(PATH) ,此处可以留空
set MYSQL=D:\mysql-5.5.57-winx64\bin\
::配置SQL备份路径
set DIR=D:\backup\db\
:: 创建备份MySQL的备份目录
if not exist %DIR% (
    mkdir %DIR% 2>nul
)
 
if not exist %DIR% (
    echo Backup path: %DIR% not exists, create dir failed.
    goto exit
)
 
echo start mysqldump ...
 
for %%i in (%databasename%) do (
    %MYSQL%mysqldump -h%host% -P%port% -u%username% -p%password% %%i > %DIR%%%i-%now%.sql 2>nul
)
 
echo end mysqldump
::记录主库状态,且做日志记录
%MYSQL%mysql -h%host% -P%port% -u%username% -p%password% -Bse "select now();show master status\G" > %DIR%MySQL_status-%now%.log
echo delete files before 60 days
::删除60天前的备份
forfiles /p "D:\backup\db" /m *.* /d -60 /c "cmd /c del @file /f"
 
:exit

在写好batch脚本后最后再在taskschd.msc中添加每天定时触发执行,具体的配置方法如下:

这里需要注意的是,这里一定要勾选上使用最高权限运行,以免造成运行失败

这里触发条件选择每天一次,具体时间可以视实际生产环境判断,开始任务则为按预定计划

在这里填上batch脚本的路径以及初始目录,其中需要注意的是一定需要配置初始目录,不然没有把batch脚本添加入PATH环境变量中该任务会找不到batch脚本从而执行失败

条件这里可以根据实际情况选择

这里一定需要勾选 允许按需运行任务,其他的时间就实际情况而定,最后在确认保存后输入用户密码这样每天系统就会自动做mysqldump逻辑备份。

本文永久更新链接地址http://www.linuxidc.com/Linux/2017-08/146485.htm

linux
本文评论   查看全部评论 (0)
表情: 表情 姓名: 字数

       

评论声明
  • 尊重网上道德,遵守中华人民共和国的各项有关法律法规
  • 承担一切因您的行为而直接或间接导致的民事或刑事法律责任
  • 本站管理人员有权保留或删除其管辖留言中的任意内容
  • 本站有权在网站内转载或引用您的评论
  • 参与本评论即表明您已经阅读并接受上述条款