手机版
你好,游客 登录 注册
背景:
阅读新闻

Groovy 2.0 新特性之:静态类型检查

[日期:2012-07-09] 来源:Linux社区  作者:Linux [字体: ]

Groovy 2.0 其中一项最大的改进就是支持静态类型检查。今天我们将对这个新特性进行全方位的介绍。

静态类型检查

Groovy 天生就是一个动态编程语言,它经常被当作是 Java 脚本语言,或者是“更好的 Java”。很多 Java 开发者经常将 Groovy 嵌入到 Java 程序中做为扩展语言来使用,更简单的描述业务规则,将来为不同的客户定制应用等等。对这样一个面向 Java 的用例,开发者不需要语言提供的所有动态特性,他们经常希望 Groovy 也提供一个类似 javac 的编译器,例如在发生一些错误的变量和方法名错误或者错误的类型赋值时就可以在编译时就知道错误,而不是运行时才报错。这就是为什么 Groovy 2.0 提供了静态类型检查功能的原因。

发现明显的错别字

静态类型检测器使用了 Groovy 已有强大的 AST (抽象语法树) 转换机制,如果你对这个机制不熟悉,你就把它当作一个可选的通过注解进行触发的编译器插件。这是一个可选的特性,可用可不用。要触发静态类型检查,只需要在方法上使用@TypeChecked 注解即可。让我们来看一个简单的例子:

 
01 import groovy.transform.TypeChecked
02   
03 void someMethod() {}
04   
05 @TypeChecked
06 void test() {
07     // compilation error:
08     // cannot find matching method sommeeMethod()
09     sommeeMethod()
10   
11     def name = "oschina"
12   
13     // compilation error:
14     // the variable naaammme is undeclared
15     println naaammme
16 }

我们使用了 @TypeCheckedtest() 方法进行注解,这让 Groovy 编译器在编译期间运行静态类型检查来检查指定的方法。当我们试图用明显错误的方法来调用 someMethod() 时,编译器将会抛出两个编译错误信息表明方法和变量为定义

检查赋值和返回值

静态类型检查还能验证返回值和变量赋值是否匹配:

 
01 import groovy.transform.TypeChecked
02   
03 @TypeChecked
04 Date test() {
05     // compilation error:
06     // cannot assign value of Date 
07     // to variable of type int
08     int object = new Date()
09   
10     String[] letters = ['o', 's', 'c']
11     // compilation error:
12     // cannot assign value of type String 
13     // to variable of type Date
14     Date aDateVariable = letters[0]
15   
16     // compilation error:
17     // cannot return value of type String 
18     // on method returning type Date
19     return "today"
20 }

在这个例子中,编译器将告诉你不能将 Date 值赋值个 int 变量,你也不能返回一个 String,因为方法已经要求是返回 Date 类型数据。代码中间的编译错误信息也很有意思,不仅是说明了错误的赋值,还给出了类型推断,因为类型检测器知道  letters[0] 的类型是 String

类型推断  type inference

因为提到了类型推断,让我们来看看其他的一些情况,我们说过类型检测器会检查返回类型和值:

 
01 import groovy.transform.TypeChecked
02   
03 @TypeChecked
04 int method() {
05     if (true) {
06         // compilation error:
07         // cannot return value of type String
08         // on method returning type int
09         'String'
10     } else {
11         42
12     }
13 }

指定了方法必须返回 int 类型值后,类型检查器将会检查各种条件判断分支的结构,包括 if/elese、try/catch、switch/case 等。在上面的例子中,如果 if 分支中返回字符串而不是 int,编译器就会报错。

自动类型转换

静态类型检查器并不会对 Groovy 支持的自动类型转换报告错误,例如对于返回  String, booleanClass 的方法,Groovy 会自动将返回值转成相应的类型:

 
01 import groovy.transform.TypeChecked
02   
03 @TypeChecked
04 boolean booleanMethod() {
05     "non empty strings are evaluated to true"
06 }
07   
08 assert booleanMethod() == true
09   
10 @TypeChecked
11 String stringMethod() {
12     // StringBuilder converted to String calling toString()
13     new StringBuilder() << "non empty string"
14 }
15   
16 assert stringMethod() instanceof String
17   
18 @TypeChecked
19 Class classMethod() {
20     // the java.util.List class will be returned
21     "java.util.List"
22 }
23   
24 assert classMethod() == List

而且静态类型检查器在类型推断方面也足够聪明:

 
01 import groovy.transform.TypeChecked
02   
03 @TypeChecked
04 void method() {
05     def name = " oschina.net "
06   
07     // String type inferred (even inside GString)
08     println "NAME = ${name.toUpperCase()}"
09   
10     // Groovy GDK method support
11     // (GDK operator overloading too)
12     println name.trim()
13   
14     int[] numbers = [1, 2, 3]
15     // Element n is an int
16     for (int n in numbers) {
17         println 
18     }
19 }

虽然变量 name 使用 def 进行定义,但类型检查器知道它的类型是 String. 因此当调用 ${name.toUpperCase()} 时,编译器知道在调用 String 的 toUpperCase() 方法和下面的 trim() 方法。当对 int 数组进行迭代时,它也能理解数组的元素类型是 int.

混合动态特性和静态类型的方法

你必须牢记于心是:静态类型检查限制了你可以在 Groovy 使用的方法。大部分运行时动态特性是不被允许的,因为他们无法在编译时进行类型检查。例如不允许在运行时通过类型的元数据类(metaclasses)来添加新方法。但当你需要使用一些例如 Groovy 的 builders 这样的动态特性时,如果你愿意,你还是可以选择静态类型检查。

@TypeChecked 注解可放在方法级别或者是类级别使用。如果你想对整个类进行类型检查,直接在类级别上放置这个注解即可,否则就在某些方法上进行注解。你也可以使用 @TypeChecked(TypeCheckingMode.SKIP) 或者是 @TypeChecked(SKIP) 来指定整个类进行类型检查除了某个方法。使用 @TypeChecked(SKIP) 必须静态引入对应的枚举类型。下面代码可以用来演示这个特性,其中greeting() 方法是需要检查的,而 generateMarkup() 方法则不用:

 
01 import groovy.transform.TypeChecked
02 import groovy.xml.MarkupBuilder
03   
04 // this method and its code are type checked
05 @TypeChecked
06 String greeting(String name) {
07     generateMarkup(name.toUpperCase())
08 }
09   
10 // this method isn't type checked
11 // and you can use dynamic features like the markup builder
12 String generateMarkup(String name) {
13     def sw =new StringWriter()
14     new MarkupBuilder(sw).html {
15         body {
16             div name
17         }
18     }
19     sw.toString()
20 }
21   
22 assert greeting("Cédric").contains("<div>CÉDRIC</div>")

类型推断和 instanceof 检查

目前的 Java 并不支持一般的类型推断,导致今天很多地方的代码往往是相当冗长,而且样板结构混乱。这掩盖了代码的实际用途,而且如果没有强大的 IDE 支持的话代码会很难写。于是就有了 instanceof 检查:你经常会在 if 条件判断语句中使用 instanceof 判断。而在 if 语句结束后,你还是必须手工对变量进行强行类型转换。而有了 Groovy 全新的类型检查模式,你可以完全避免这种情况出现:

 
01 import groovy.transform.TypeChecked
02 import groovy.xml.MarkupBuilder
03   
04 @TypeChecked
05 String test(Object val) {
06     if (val instanceof String) {
07         // unlike Java: 
08         // return ((String)val).toUpperCase()
09         val.toUpperCase()
10     } else if (val instanceof Number) {
11         // unlike Java: 
12         // return ((Number)val).intValue().multiply(2)
13         val.intValue() * 2
14     }
15 }
16   
17 assert test('abc') == 'ABC'
18 assert test(123) == '246'

上述例子中,静态类型检查器知道 val 参数在 if 块中是 String 类型,而在 else if 块中是 Number 类型,无需再做任何手工类型转换。

最低上限 Lowest Upper Bound

静态类型检测器比一般理解的对象类型诊断要更深入一些,请看如下代码:

 
1 import groovy.transform.TypeChecked
2   
3 // inferred return type:
4 // a list of numbers which are comparable and serializable
5 @TypeChecked test() {
6     // an integer and a BigDecimal
7     return [1234, 3.14]
8 }

在这个例子中,我们返回了数值列表,包括 IntegerBigDecimal. 但静态类型检查器计算了一个最低的上限,实际上是一组可序列化(Serializable)和可比较(Comparable)的数值。而 Java 是不可能表示这种类型的,但如果我们使用一些交集运算,那看起来就应该是 List<Number & Serializable & Comparable>.

不同对象类型的变量 Flow typing

虽然这可能不是一个好的方法,但有时候开发者会使用一些无类型的变量来存储不同类型的值,例如:

 
01 import groovy.transform.TypeChecked
02   
03 @TypeChecked test() {
04     def var = 123            // inferred type is int
05     var = "123"              // assign var with a String
06   
07     println var.toInteger()  // no problem, no need to cast
08   
09     var = 123
10     println var.toUpperCase() // error, var is int!
11 }

上面代码中 var 变量一开始是 int 类型,后来又赋值了字符串,“flow typing”算法可以理解赋值的顺序,并指导 var 当前是字符串类型,这样调用 Groovy 为 String 增加的 toInteger() 方法就没问题。紧接着又赋值整数给 var 变量,但现在如果再次调用 toUpperCase() 就会报出编译错误。

还有另外一些关于 “flow typing” 算法的特殊情况,当某个变量在一个闭包中被共享该会是怎么样的一种情况呢?

 
01 import groovy.transform.TypeChecked
02   
03 @TypeChecked test() {
04     def var = "abc"
05     def cl = {
06         if (new Random().nextBoolean()) var = new Date()
07     }
08     cl()
09     var.toUpperCase() // compilation error!
10 }

var 本地变量先赋值了一个字符串,但是在闭包中会在一些随机的情况下被赋值为日期类型数值。一般情况下这种只能在运行时才能报错,因为这种错误是随机发生的。因此在编译时,编译器是没有机会知道 var 变量是字符串还是日期,这就是为什么编译器无法得知错误的原因。尽管这个例子有点做作,但还有更有趣的情况:

 
01 import groovy.transform.TypeChecked
02   
03 class A          { void foo() {} }
04 class B extends A { void bar() {} }
05   
06 @TypeChecked test() {
07     def var = new A()
08     def cl = { var = new B() }
09     cl()
10     // var is at least an instance of A
11     // so we are allowed to call method foo()
12     var.foo()
13 }

test() 方法中,var 先被赋值为 A 的实例,紧接着在闭包中被赋值为 B 的实例,然后调用这个闭包方法,因此我们至少可以诊断 var 最后的类型是 A。

Groovy 编译器的所有这些检查都是在编译时就完成了,但生成的字节码还是跟一些动态代码一样,在行为上没有任何改变。

Groovy 的详细介绍请点这里
Groovy 的下载地址请点这里

相关阅读: Groovy入门教程 http://www.linuxidc.com/Linux/2013-09/89776.htm

linux
相关资讯       groovy 
本文评论   查看全部评论 (0)
表情: 表情 姓名: 字数

       

评论声明
  • 尊重网上道德,遵守中华人民共和国的各项有关法律法规
  • 承担一切因您的行为而直接或间接导致的民事或刑事法律责任
  • 本站管理人员有权保留或删除其管辖留言中的任意内容
  • 本站有权在网站内转载或引用您的评论
  • 参与本评论即表明您已经阅读并接受上述条款