手机版
你好,游客 登录 注册 搜索
背景:
阅读新闻

Oracle 关于身份证校验规则详细说明(附有代码复制可执行)

[日期:2018-07-14] 来源:Linux社区  作者:ljs05 [字体: ]

身份证号码组成

15位身份证号组成:

省份(2位)市(2位)区[县](2位)年(2位)月(2位)日(2位)+3位序列号 [奇数给男性/偶数给女性]

18位身份证号组成:

省份(2位)市(2位)区[县](2位)年(4位)月(2位)日(2位)+2位序列号+1位性别[奇数给男性/偶数给女性]+1位校验码

注意:

1)(身份证号码第七位到第十四位)表示编码对象出生的年、月、日,其中年份用四位数字表示,年、月、日之间不用分隔符。

2)(身份证号码第十五位到十七位)地址码所标识的区域范围内,对同年、月、日出生的人员编定的顺序号。其中第十七位奇数分给男性,偶数分给女性。

3)(身份证号码最后一位)是根据前面十七位数字码,按照ISO 7064:1983.MOD 11-2校验码计算出来的检验码。作为尾号的校验码,主要是为了校验计算机输入公民身份证号码的前17位数字是否正确,是由号码编制单位按统一的公式计算出来的,如果某人的尾号是0-9,都不会出现X,但如果尾号是10,那么就得用X来代替,因为如果用10做尾号,那么此人的身份证就变成了19位,而19位的号码违反了国家标准,并且中国的计算机用用系统也不承认19位的身份证号码。Ⅹ是罗马数字的10,用X来代替10,可以保证公民的身份证符合国家标准。

三、校验码的计算方法

1、将前面的身份证号码17位数分别乘以不同的系数。从第一位到第十七位的系数分别为:7-9-10-5-8-4-2-1-6-3-7-9-10-5-8-4-2。

2、将这17位数字和系数相乘的结果相加。

3、用加出来和除以11,看余数是多少?

4、余数只可能有0-1-2-3-4-5-6-7-8-9-10这11个数字。其分别对应的最后一位身份证的号码为1-0-X -9-8-7-6-5-4-3-2。

5、通过上面得知如果余数是2,身份证的最后一位号码就是罗马数字x。如果余数是10,就会在身份证的第18位数字上出现的是2。

例如:某男性的身份证号码 我们要看看这个身份证是不是合法的身份证。45010119890620001X(仅测试使用)

首先我们得出前17位的乘积和是244,然后用244除以11得出的结果是17+2/11,也就是说其余数是2。最后通过对应规则就可以知道余数2对应的是罗马数字X。可以判定这是一个合格的身份证号码。

CREATE OR REPLACE PROCEDURE PRC_身份证校验(ID_NUMBER    IN VARCHAR2, --身份证号的输入
                                      ID_SEX        OUT VARCHAR2, --性别
                                      ID_AGE        OUT NUMBER, --年龄
                                      ID_BRITHDAY  OUT DATE, --出生时间
                                      ID_NUMBER_END OUT VARCHAR2, --最后校验的身份证
                                      ID_CODE      OUT NUMBER,
                                      ID_ERROR      OUT VARCHAR2) IS

  --15位身份证号组成:
  --省份(2位)市(2位)区[县](2位)年(2位)月(2位)日(2位)+3位序列号 [奇数给男性/偶数给女性]

  --18位身份证号组成:
  --省份(2位)市(2位)区[县](2位)年(4位)月(2位)日(2位)+2位序列号+1位性别[奇数男/偶数女]+1位校验码

  --ID_CODE返回值分别为1、-1、-2、-3、-4五类信息,负值表示身份证信息有误
  --返回1:表示身份证正确。
  --返回-1:表示系统错误,一般不会出现这个值。
  --返回-2:表示身份证位数有误。
  --返回-3:表示出生日期有误或者身份证含有不正确的信息。
  --返回-4:表示身份证最后一位校验位有误。

  --声明数组变量
  --声明N数组 用于存放身份证系数(加权因子)7,9,10,5,8,4,2,1,6,3,7,9,10,5,8,4,2
  TYPE N IS VARRAY(18) OF INTEGER;
  --声明S数组 用于存放求MOD得的余数'1','0','X','9','8','7','6','5','4','3','2'
  TYPE S IS VARRAY(11) OF VARCHAR2(11);
  I            INTEGER;
  ID_MONTH    NUMBER; --记录身份证上的月份
  ID_DAY      NUMBER; --记录身份证上的日期
  JQYZ_N      N; --将数组N的值赋予JQYZ_N(校验因子)
  YS_S        S; --将数组S的值赋予YS_S(校验余数) 
  ID_SUM      INTEGER; --身份证号分别乘以加权因子的总和
  ID_TMP_15_18 VARCHAR2(18); --存储15位身份证转18位身份证年龄前+19
  ID_SUM_MOD  VARCHAR2(2); --存储加权因子总和MOD11取余数,得到身份证最后一位检验位
BEGIN
  ID_CODE  := 1;
  ID_ERROR := NULL;
  ID_DAY  := 0;
  ID_MONTH := 0;
  JQYZ_N  := N(7, 9, 10, 5, 8, 4, 2, 1, 6, 3, 7, 9, 10, 5, 8, 4, 2);
  YS_S    := S('1', '0', 'X', '9', '8', '7', '6', '5', '4', '3', '2');
  ID_SUM  := 0;
  IF LENGTHB(ID_NUMBER) = 15 THEN
    BEGIN
      ID_TMP_15_18 := SUBSTRB(ID_NUMBER, 0, 6) || '19' ||
                      SUBSTRB(ID_NUMBER, 7); --得到18位身份证
      --循环计算身份证前17位和权加因子的相乘得到的总合
      FOR I IN 1 .. 17 LOOP
        ID_SUM := ID_SUM +
                  TO_NUMBER(SUBSTRB(ID_TMP_15_18, I, 1)) * JQYZ_N(I);
      END LOOP;
      --将得到的总合除以11得到一个余数,余数对应相应值
      ID_SUM_MOD := YS_S(MOD(ID_SUM, 11) + 1);
      --性别取值
      SELECT DECODE(MOD(TO_NUMBER(SUBSTRB(ID_NUMBER, 15, 1)), 2),
                    0,
                    '女',
                    '男')
        INTO ID_SEX
        FROM DUAL;
      --出生时间取值
      ID_MONTH := TO_NUMBER(SUBSTRB(ID_TMP_15_18, 11, 2));
      ID_DAY  := TO_NUMBER(SUBSTRB(ID_TMP_15_18, 13, 2));
      IF (ID_MONTH > 0) AND (ID_MONTH < 13) THEN
        IF (ID_DAY > 0) AND (ID_DAY <= 31) THEN
          BEGIN
            ID_BRITHDAY := TO_DATE(SUBSTRB(ID_TMP_15_18, 7, 8), 'YYYYMMDD');
          EXCEPTION
            WHEN OTHERS THEN
              ID_CODE  := -1;
              ID_ERROR := '出生时间格式有误,请核实。';
          END;
        ELSE
          ID_CODE  := -3;
          ID_ERROR := '您输入日(' || ID_DAY || ')格式不符合要求(1-31号)';
        END IF;
      ELSE
        ID_CODE  := -3;
        ID_ERROR := '您输入月(' || ID_MONTH || ')格式不符合要求(1-12月份)';
      END IF;
      --计算年龄
      ID_AGE := TRUNC(MONTHS_BETWEEN(SYSDATE, ID_BRITHDAY) / 12);
      --得出最后身份证号
      ID_NUMBER_END := ID_TMP_15_18 || UPPER(ID_SUM_MOD);
    END;
  ELSIF LENGTHB(ID_NUMBER) = 18 THEN
    BEGIN
      --循环计算身份证前17位和权加因子的相乘得到的总合
      FOR I IN 1 .. 17 LOOP
        ID_SUM := ID_SUM + TO_NUMBER(SUBSTRB(ID_NUMBER, I, 1)) * JQYZ_N(I);
      END LOOP;
      --将得到的总合除以11得到一个余数,余数对应相应值
      ID_SUM_MOD := YS_S(MOD(ID_SUM, 11) + 1);
      IF UPPER(SUBSTRB(ID_NUMBER, 18, 1)) != upper(ID_SUM_MOD) THEN
        ID_CODE  := -4;
        ID_ERROR := '身份证最后一位校验位有误,应为(' || ID_SUM_MOD || ')';
      END IF;
      --性别取值
      SELECT DECODE(MOD(TO_NUMBER(SUBSTRB(ID_NUMBER, 17, 1)), 2),
                    0,
                    '女',
                    '男')
        INTO ID_SEX
        FROM DUAL;
      --出生时间取值
      ID_MONTH := TO_NUMBER(SUBSTRB(ID_NUMBER, 11, 2));
      ID_DAY  := TO_NUMBER(SUBSTRB(ID_NUMBER, 13, 2));
      IF (ID_MONTH > 0) AND (ID_MONTH < 13) THEN
        IF (ID_DAY > 0) AND (ID_DAY <= 31) THEN
          BEGIN
            ID_BRITHDAY := TO_DATE(SUBSTRB(ID_NUMBER, 7, 8), 'YYYYMMDD');
          EXCEPTION
            WHEN OTHERS THEN
              ID_CODE  := -1;
              ID_ERROR := '出生时间格式有误,请核实。';
          END;
        ELSE
          ID_CODE  := -3;
          ID_ERROR := '您输入日(' || ID_DAY || ')格式不符合要求(1-31号)';
        END IF;
      ELSE
        ID_CODE  := -3;
        ID_ERROR := '您输入月(' || ID_MONTH || ')格式不符合要求(1-12月份)';
      END IF;
      --计算年龄
      ID_AGE := TRUNC(MONTHS_BETWEEN(SYSDATE, ID_BRITHDAY) / 12);
      --得出最后身份证号
      ID_NUMBER_END := substrb(ID_NUMBER, 1, 17) || upper(ID_SUM_MOD);
    END;
  ELSE
    ID_CODE  := -2;
    ID_ERROR := '该身份证号:' || ID_NUMBER || ' 不符合要求';
  END IF;
EXCEPTION
  WHEN OTHERS THEN
    ID_CODE  := -1;
    ID_ERROR := '系统发生未知错误'; --一般不会发生该错误
END PRC_身份证校验;

Linux公社的RSS地址:https://www.linuxidc.com/rssFeed.aspx

本文永久更新链接地址https://www.linuxidc.com/Linux/2018-07/153130.htm

linux
相关资讯       Oracle身份证校验规则 
本文评论   查看全部评论 (0)
表情: 表情 姓名: 字数

       

评论声明
  • 尊重网上道德,遵守中华人民共和国的各项有关法律法规
  • 承担一切因您的行为而直接或间接导致的民事或刑事法律责任
  • 本站管理人员有权保留或删除其管辖留言中的任意内容
  • 本站有权在网站内转载或引用您的评论
  • 参与本评论即表明您已经阅读并接受上述条款