手机版
你好,游客 登录 注册 搜索
背景:
阅读新闻

awk 命令使用入门基础详解

[日期:2019-08-01] 来源:Linux社区  作者:Linux [字体: ]

1. awk简介

awk是一种编程语言,用于在linux/unix下对文本和数据进行处理。数据可以来自标准输入、一个或多个文件,或其它命令的输出。它支持用户自定义函数和动态正则表达式等先进功能,是linux/unix下的一个强大编程工具。它在命令行中使用,但更多是作为脚本来使用。

awk的处理文本和数据的方式是这样的,它逐行扫描文件,从第一行到最后一行,寻找匹配的特定模式的行,并在这些行上进行你想要的操作。如果没有指定处理动作,则把匹配的行显示到标准输出(屏幕),如果没有指定模式,则所有被操作所指定的行都被处理

2. awk命令格式和选项

2.1. awk的语法有两种形式

  • awk [options] 'script' var=value file(s)

  • awk [options] -f scriptfile var=value file(s)

2.2. 命令选项

  • -F fs or --field-separator fs
    指定输入文件折分隔符,fs是一个字符串或者是一个正则表达式,如-F:
  • -v var=value or --asign var=value
    赋值一个用户定义变量。
  • -f scripfile or --file scriptfile
    从脚本文件中读取awk命令。
  • -mf nnn and -mr nnn
    对nnn值设置内在限制,-mf选项限制分配给nnn的最大块数目;-mr选项限制记录的最大数目。
    这两个功能是Bell实验室版awk的扩展功能,在标准awk中不适用。
  • -W compact or --compat, -W traditional or --traditional
    在兼容模式下运行awk。所以gawk的行为和标准的awk完全一样,所有的awk扩展都被忽略。
  • -W copyleft or --copyleft, -W copyright or --copyright
    打印简短的版权信息。
  • -W help or --help, -W usage or --usage
    打印全部awk选项和每个选项的简短说明。
  • -W lint or --lint
    打印不能向传统unix平台移植的结构的警告。
  • -W lint-old or --lint-old
    打印关于不能向传统unix平台移植的结构的警告。
  • -W posix
    打开兼容模式。但有以下限制,不识别:\x、函数关键字、func、换码序列以及当fs是一个空格时,将新行作为一个域分隔符;操作符****=不能代替^^=;fflush无效。
  • -W re-interval or --re-inerval
    允许间隔正则表达式的使用,参考(grep中的Posix字符类),如括号表达式[[:alpha:]]
  • -W source program-text or --source program-text
    使用program-text作为源代码,可与-f命令混用。
  • -W version or --version
    打印bug报告信息的版本。

3. 模式和操作

  • awk脚本是由模式和操作组成的:

  • pattern {action}

两者是可选的,如果没有模式,则action应用到全部记录,如果没有action,则输出匹配全部记录。默认情况下,每一个输入行都是一条记录,但用户可通过RS变量指定不同的分隔符进行分隔。

3.1. 模式

模式可以是以下任意一个:

  • /正则表达式/:使用通配符的扩展集。

  • 关系表达式:可以用下面运算符表中的关系运算符进行操作,可以是字符串或数字的比较,如$2>%1选择第二个字段比第一个字段长的行。

  • 模式匹配表达式:用运算符~(匹配)和~!(不匹配)。

  • 模式,模式:指定一个行的范围。该语法不能包括BEGIN和END模式。

  • BEGIN:让用户指定在第一条输入记录被处理之前所发生的动作,通常可在这里设置全局变量。

  • END:让用户在最后一条输入记录被读取之后发生的动作。

3.2. 操作

操作由一人或多个命令、函数、表达式组成,之间由换行符或分号隔开,并位于大括号内。主要有四部份:

  • 变量或数组赋值

  • 输出命令

  • 内置函数

  • 控制流命令

4. awk的环境变量

 

Table 1. awk的环境变量

变量描述
$n 当前记录的第n个字段,字段间由FS分隔。
$0 完整的输入记录。
ARGC 命令行参数的数目。
ARGIND 命令行中当前文件的位置(从0开始算)。
ARGV 包含命令行参数的数组。
CONVFMT 数字转换格式(默认值为%.6g)
ENVIRON 环境变量关联数组。
ERRNO 最后一个系统错误的描述。
FIELDWIDTHS 字段宽度列表(用空格键分隔)。
FILENAME 当前文件名。
FNR 同NR,但相对于当前文件。
FS 字段分隔符(默认是任何空格)。
IGNORECASE 如果为真,则进行忽略大小写的匹配。
NF 当前记录中的字段数。
NR 当前记录数。
OFMT 数字的输出格式(默认值是%.6g)。
OFS 输出字段分隔符(默认值是一个空格)。
ORS 输出记录分隔符(默认值是一个换行符)。
RLENGTH 由match函数所匹配的字符串的长度。
RS 记录分隔符(默认是一个换行符)。
RSTART 由match函数所匹配的字符串的第一个位置。
SUBSEP 数组下标分隔符(默认值是\034)。

5. awk运算符

 

Table 2. 运算符

运算符描述
= += -= *= /= %= ^= **= 赋值
?: C条件表达式
|| 逻辑或
&& 逻辑与
~     ~! 匹配正则表达式和不匹配正则表达式
< <= > >= != == 关系运算符
空格 连接
+ - 加,减
* / & 乘,除与求余
+ - ! 一元加,减和逻辑非
^ *** 求幂
++ -- 增加或减少,作为前缀或后缀
$ 字段引用
in 数组成员

6. 记录和域

6.1. 记录

awk把每一个以换行符结束的行称为一个记录。

记录分隔符:默认的输入和输出的分隔符都是回车,保存在内建变量ORS和RS中。

$0变量:它指的是整条记录。例如:  $ awk '{print $0}' test  #将输出test文件中的所有记录。

变量NR:一个计数器,每处理完一条记录,NR的值就增加1。如$ awk '{print NR,$0}' test将输出test文件中所有记录,并在记录前显示记录号。

6.2. 域

记录中每个单词称做“域”,默认情况下以空格或tab分隔。awk可跟踪域的个数,并在内建变量NF中保存该值。例如:

$ awk '{print $1,$3}' test    #将打印test文件中第一和第三个以空格分开的列()

6.3. 域分隔符

内建变量FS保存输入域分隔符的值,默认是空格或tab。我们可以通过-F命令行选项修改FS的值。如$ awk -F: '{print $1,$5}' test将打印以冒号为分隔符的第一,第五列的内容。

可以同时使用多个域分隔符,这时应该把分隔符写成放到方括号中,例如:

$awk -F'[:\t]' '{print $1,$3}' test     #表示以空格、冒号和tab作为分隔符。

输出域的分隔符默认是一个空格,保存在OFS中。例如:

$ awk -F: '{print $1,$5}' test    #$1和$5间的逗号就是OFS的值。

7. gawk专用正则表达式元字符

以下几个是gawk专用的,不适合unix版本的awk。

\Y
匹配一个单词开头或者末尾的空字符串。
\B
匹配单词内的空字符串。
\<
匹配一个单词的开头的空字符串,锚定开始。
\>
匹配一个单词的末尾的空字符串,锚定末尾。
\w
匹配一个字母数字组成的单词。
\W
匹配一个非字母数字组成的单词。
\‘
匹配字符串开头的一个空字符串。
\'
匹配字符串末尾的一个空字符串

 

8. POSIX字符集

 

9. 匹配操作符(~)

用来在记录或者域内匹配正则表达式。

$ awk '$1 ~/^root/' test    #将显示test文件第一列中以root开头的行。

 

10. 比较表达式

conditional expression1 ? expression2: expression3

例如:

$ awk '$1 > $3 ? max=$1: max=$3 {print max}' test #如果第一个域大于第三个域,$1就赋值给max,否则$3就赋值给max。
$ awk '$1 + $2 > 100' test  #如果第一和第二个域相加大于100,则打印这些行。
$ awk '$1 > 5 && $2 < 10' test  #如果第一个域大于5,并且第二个域小于10,则打印这些行。

11. 范围模板

范围模板匹配从第一个模板的第一次出现到第二个模板的第一次出现之间所有行。如果有一个模板没出现,则匹配到开头或末尾。

$ awk '/root/,/mysql/' test   #将显示root第一次出现到mysql第一次出现之间的所有行。

12. 一个验证passwd文件有效性的例子

$ cat /etc/passwd | awk -F: '\
NF != 7{\
printf("line %d,does not have 7 fields:%s\n",NR,$0)}\
$1 !~ /[A-Za-z0-9]/{printf("line %d,non alpha and numeric user id:%d: %s\n,NR,$0)}\$2 == "*" {printf("line %d, no password: %s\n",NR,$0)}'
  •  

cat把结果输出给awk,awk把域之间的分隔符设为冒号。

  •  

如果域的数量(NF)不等于7,就执行下面的程序。

  •  

printf打印字符串"line ?? does not have 7 fields",并显示该条记录。

  •  

如果第一个域没有包含任何字母和数字,printf打印“no alpha and numeric user id" ,并显示记录数和记录。

  •  

如果第二个域是一个星号,就打印字符串“no passwd”,紧跟着显示记录数和记录本身。

13. 几个实例

$ awk '/^(no|so)/' test    #打印所有以no或so开头的行。

$ awk '/^[ns]/{print $1}' test    #如果记录以n或s开头,就打印这个记录。

$ awk '$1 ~/[0-9][0-9]$/{print $1}' test   #如果第一个域以两个数字结束就打印这个记录。

$ awk '$1 == 100 || $2 < 50' test    #如果第一个域等于100或第二个域小于50,则打印该行。

$ awk '$1 != 10' test    #如果第一个域不等于10就打印该行。

$ awk '/test/{print $1 + 10}' test    #如果记录包含test,则第一个域加10并打印出来。

$ awk '{print ($1 > 5 ? "ok "$1: "error"$1)}' test  #如果第一个域大于5则打印冒号前面表达式值,否则打印冒号后面的表达式值。

$ awk '/^root/,/^mysql/' test    #打印以root开头的记录到以mysql开头的记录范围内的所有记录。如果找到一个新的正则表达式root开头的记录,则继续打印直到下一个以正则表达式mysql开头的记录为止,或到文件末尾。

14. awk编程

14.1. 变量

  • 在awk中,变量不需要定义就可以直接使用,变量类型可以是数字或字符串。

  • 赋值格式:Variable = expression,例如:

$ awk '$1 ~/test/{count = $2 + $3; print count}' test  # 如果第一个域匹配test,就把第二和第三个域的值相加,并把结果赋值给变量count,最后打印出来。
  • awk可以在命令行中给变量赋值,然后将这个变量传输给awk脚本。例如:

$ awk -F: -f awkscript month=4 year=2004 test  #为自定义变量month和year分别赋值为42004。这些变量在awkscript脚本中使用起来就象是在脚本中建立的一样。注意,如果参数前面出现test,那么在BEGIN语句中的变量就不能被使用。
  • 域变量也可被赋值和修改,例如:

$ awk '{$2 = 100 + $1; print }' test  #如果第二个域不存在,awk将计算表达式100加$1的值,并将其赋值给$2,如果第二个域存在,则用表达式的值覆盖$2原来的值。
$ awk '$1 == "root"{$1 ="test";print}' test  #如果第一个域的值是“root”,则把它赋值为“test”,注意,字符串一定要用双引号。
  • 内建变量的使用。变量列表在前面已列出,现在举个例子说明一下:

$ awk -F: '{IGNORECASE=1; $1 == "MARY"{print NR,$1,$2,$NF}'test  #把IGNORECASE设为1代表忽略大小写,打印第一个域是mary的记录数、第一个域、第二个域和最后一个域。

14.2. BEGIN模块

BEGIN模块后紧跟着动作块,这个动作块在awk处理任何输入文件之前执行。所以它可以在没有任何输入的情况下进行测试。它通常用来改变内建变量的值,如OFS,RS和FS等,以及打印标题。例如:

$ awk 'BEGIN{FS=":"; OFS="\t"; ORS="\n\n"}{print $1,$2,$3} test   #在处理输入文件以前,域分隔符(FS)被设为冒号,输出文件分隔符(OFS)被设置为制表符,输出记录分隔符(ORS)被设置为两个换行符。
$ awk 'BEGIN{print "TITLE TEST"}'   #只打印标题。

14.3. END模块

END不匹配任何的输入文件,但是执行动作块中的所有动作,它在整个输入文件处理完成后被执行。例如:

$ awk 'END{print "The number of records is" NR}' test   #打印所有被处理的记录数(总行数)。

14.4. 重定向和管道

  • awk可使用shell的重定向符进行重定向输出,例如:

$ awk '$1 = 100 {print $1 > "output_file" }' test    #如果第一个域的值等于100,则把它输出到output_file中。也可以用>>做追加操作。
  • 输出重定向需用到getline函数。getline从标准输入、管道或者当前正在处理的文件之外的其他输入文件获得输入。它负责从输入获得下一行的内容,并给NF,NR和FNR等内建变量赋值。如果得到一条记录,getline函数返回1,如果到达文件的末尾就返回0,如果出现错误,例如打开文件失败,就返回-1。例如:

#执行linux的date命令,并通过管道输出给getline,然后再把输出赋值给自定义变量d,并打印它。
$ awk 'BEGIN{ "date" | getline d; print d}' test 
 
#执行shell的date命令,并通过管道输出给getline,然后getline从管道中读取并将输入赋值给d,split函数把变量d转化成数组mon,然后打印数组mon的第二个元素。  
$ awk 'BEGIN{"date" | getline d; split(d,mon); print mon[2]}' test 
   
#命令ls的输出传递给geline作为输入,循环使getline从ls的输出中读取一行,并把它打印到屏幕。这里没有输入文件,因为BEGIN块在打开输入文件前执行,所以可以忽略输入文件。
$ awk 'BEGIN{while( "ls" | getline) print}'   

#在屏幕上打印”What is your name?",并等待用户应答。当一行输入完毕后,getline函数从终端接收该行输入,并把它储存在自定义变量name中。如果第一个域匹配变量name的值,print函数就被执行,END块打印See you和name的值。
$ awk 'BEGIN{printf "What is your name?" ; getline name < "/dev/tty"} $1 ~name {print "Found " name " on line " NR "."} END{print "See you," name "."}' test

#awk将逐行读取文件/etc/passwd的内容,在到达文件末尾前,计数器lc一直增加,当到末尾时,打印lc的值。
#注意,如果文件不存在,getline返回-1,如果到达文件的末尾就返回0,如果读到一行,就返回1,所以命令 while (getline < "/etc/passwd")在文件不存在的情况下将陷入无限循环,因为返回-1表示逻辑真。
$ awk 'BEGIN{while (getline < "/etc/passwd" > 0) lc++; print lc}'
  • 可以在awk中打开一个管道,且同一时刻只能有一个管道存在。通过close()可关闭管道。例如:

$ awk '{print $1, $2 | "sort" } END {close("sort")}' test  #awd把print语句的输出通过管道作为linux命令sort的输入,END块执行关闭管道操作。
  • system函数可以在awk中执行linux的命令。例如:

$ awk 'BEGIN{system("clear")}'
  • fflush函数用以刷新输出缓冲区,如果没有参数,就刷新标准输出的缓冲区,如果以空字符串为参数,如fflush(""),则刷新所有文件和管道的输出缓冲区。

 

14.5. 条件语句

awk中的条件语句是从C语言中借鉴过来的,可控制程序的流程。

14.5.1. if 语句

格式:
        {if (expression){
                   statement; statement; ...
                     }
        }
$ awk '{if ($1 <$2) print $2 " too high"}' test   #如果第一个域小于第二个域则打印。
$ awk '{if ($1 < $2) {count++; print count" ok"}} END{print count" is ok!"}' test   #如果第一个域小于第二个域,则count加一,并打印ok并统计总数

14.5.2. if/else语句,用于双重判断

格式:
        {if (expression){
                   statement; statement; ...
                       }
        else{
                   statement; statement; ...
                       }
        }

 

$ awk '{if ($1 > 100) print $1 " is too big" ; else print "ok"}' test   #如果$1大于100则打印$1 bad,否则打印ok。
$ awk '{if ($1 > 100){ count++; print $1} else {count--; print $2}}' test   #如果$1大于100,则count加一,并打印$1,否则count减一,并打印$2

14.5.3. if/else else if语句,用于多重判断。

格式:
        {if (expression){
                    statement; statement; ...
                   }
        else if (expression){
                    statement; statement; ...
                   }
        else if (expression){
                    statement; statement; ...
                   }
        else {
                   statement; statement; ...
             }
        }

 

14.6. 循环

  • awk有三种循环: while循环;for循环;special for循环。

#变量i初始值为1,若i小于或等于NF(记录域总数),文件第一列自相加,并执行打印语句。
$ awk '{ i = 1; while ( i <= NF ) { print NF,$i; i++}}' test
$ awk '{for (i = 1; i<NF; i++) print NF,$i}' test   #作用同上。
  • bread continue 语句。break用于在满足条件的情况下跳出循环;continue用于在满足条件的情况下忽略后面的语句,直接返回循环的顶端。如:

awk '{for ( x=3; x<=NF; x++) if ($x<0){print NR" line Bottomed out!"; break} else if ($x>=0){print NR" line Get next item"; continue}}' test
  • next 语句从输入文件中读取一行,然后从头开始执行awk脚本。如:

awk '{if ($1 ~/test/){next} else {print}}' test
  • exit 语句用于结束awk程序,但不会略过END块。退出状态为0代表成功,非零值表示出错。

14.7. 数组

awk中的数组的下标可以是数字和字母,称为关联数组。

14.7.1. 下标与关联数组

  • 用变量作为数组下标。例如:

$ awk {name[x++]=$2};END{for(i=0;i<NR;i++) print i,name[i]}' test   
#数组name中的下标是一个自定义变量x(初始化值为0),读取一行内容后增加1,并将每行第二个域的值赋给name数组的各个元素。\
#在END模块中,for循环被用于循环整个数组,从下标为0的元素开始,打印那些存储在数组中的值。因为下标是关健字,所以它不一定从0开始,可以从任何值开始。
  • special for 循环用于读取关联数组中的元素。格式如下:

{for (item in arrayname){
         print arrayname[item]
         }
}
$ awk '/^tom/{name[NR]=$1}; END{for(i in name){print name[i]}}' test    
#打印有值的数组元素。打印的顺序是随机的。
  • 用字符串作为下标。如:count["test"]

  • 用域值作为数组的下标。一种新的for循环方式,for (index_value in array) statement。例如:

$ awk '{count[$1]++} END{for(name in count) print name,count[name]}' test
#该语句将打印$1中字符串出现的次数。它首先以第一个域作数组count的下标,第一个域变化,索引就变化。
  • delete 函数用于删除数组元素。例如:

$ awk '{line[x++]=$1} END{for(x in line) delete line[x]}' test
#分配给数组line的是第一个域的值,所有记录处理完成后,special for循环将删除每一个元素。

14.8. awk的内建函数

14.8.1. 字符串函数

  • sub 函数匹配记录中最大、最靠左边的子字符串的正则表达式,并用替换字符串替换这些字符串。如果没有指定目标字符串就默认使用整个记录。替换只发生在第一次匹配的时候。格式如下:

sub (regular expression, substitution string):
sub (regular expression, substitution string, target string)

  实例:

$ awk '{ sub(/test/, "mytest"); print }' test
#在整个记录中匹配,只替换每行第一次匹配到字段。如要替换每行匹配到的所有字段需要用到gsub

$ awk '{ sub(/test/, "mytest",$2); print }' test
#在整个记录的第二个域中进行匹配,只替换每行第一次匹配到字段。
  • gsub 函数作用如sub,但它在整个文档中进行匹配。格式如下:

  实例:

$ awk '{ gsub(/test/, "mytest"); print }' testfile   #文档中匹配test,匹配的都被替换成mytest。
$ awk '{ gsub(/test/, "mytest" , $2) }; print }' testfile   #文档的第二个域中匹配,所有匹配的都被替换成mytest。
  • index 函数返回子字符串第一次被匹配的位置,偏移量从位置1开始。格式如下:

index(string, substring)

  实例:

$ awk '{ print index("mytest", "test") }' test
#实例返回test在mytest的位置,结果应该是3
  • length 函数返回记录的字符数。格式如下:

length( string )
length

  实例:

$ awk '{ print length( "test" ) }'   #返回test字符串的长度
$ awk '{ print length }' test          #返回test文件中第条记录的字符数
  • split 函数可按给定的分隔符把字符串分割为一个数组。如果分隔符没提供,则按当前FS值进行分割。格式如下:

split( string, array, field separator )
split( string, array )

  实例:

$ awk '{ split( "20:18:00", time, ":" ); print time[2] }'
#上例把时间按冒号分割到time数组内,并显示第二个数组元素18
  • substr 函数返回从位置1开始的子字符串,如果指定长度超过实际长度,就返回整个字符串。格式如下:

substr( string, starting position )
substr( string, starting position, length of string )

  实例:

$ awk '{ print substr( "hello world", 7,11 ) }'     #截取了world子字符串。
  • match 函数返回在字符串中正则表达式位置的索引,如果找不到指定的正则表达式则返回0。match函数会设置内建变量RSTART为字符串中子字符串的开始位置,RLENGTH为到子字符串末尾的字符个数。substr可利于这些变量来截取字符串。函数格式如下:

match( string, regular expression )

  实例:

$ awk '{start=match("this is a test",/[a-z]+$/); print start}'
#打印以连续小写字符结尾的开始位置,这里是11。

$ awk '{start=match("this is a test",/[a-z]+$/); print start, RSTART, RLENGTH }'
#打印RSTART和RLENGTH变量,这里是11(start)11(RSTART)4(RLENGTH)
  • toupper 和tolower 函数可用于字符串大小间的转换,该功能只在gawk中有效。格式如下:

toupper( string )
tolower( string )

  实例:

$ awk '{ print toupper("test"), tolower("TEST") }'

 

14.8.2. 时间函数

  • systime函数返回从1970年1月1日开始到当前时间(不计闰年)的整秒数。格式如下:

systime()
  • 实例:

$ awk '{ now = systime(); print now }'
  • strftime函数使用C库中的strftime函数格式化时间。格式如下:

systime( [format specification][,timestamp] )
  •  

    Table 3. 日期和时间格式说明符

    格式描述
    %a 星期几的缩写(Sun)
    %A 星期几的完整写法(Sunday)
    %b 月名的缩写(Oct)
    %B 月名的完整写法(October)
    %c 本地日期和时间
    %d 十进制日期
    %D 日期 08/20/99
    %e 日期,如果只有一位会补上一个空格
    %H 用十进制表示24小时格式的小时
    %I 用十进制表示12小时格式的小时
    %j 从1月1日起一年中的第几天
    %m 十进制表示的月份
    %M 十进制表示的分钟
    %p 12小时表示法(AM/PM)
    %S 十进制表示的秒
    %U 十进制表示的一年中的第几个星期(星期天作为一个星期的开始)
    %w 十进制表示的星期几(星期天是0)
    %W 十进制表示的一年中的第几个星期(星期一作为一个星期的开始)
    %x 重新设置本地日期(08/20/99)
    %X 重新设置本地时间(12:00:00)
    %y 两位数字表示的年(99)
    %Y 当前月份
    %Z 时区(PDT)
    %% 百分号(%)

    实例:

$ awk '{ now=strftime( "%D", systime() ); print now }'
            $ awk '{ now=strftime("%m/%d/%y"); print now }'

14.8.3. 内建数学函数

 

Table 4. 

函数名称返回值
atan2(x,y) y,x范围内的余切
cos(x) 余弦函数
exp(x) 求幂
int(x) 取整
log(x) 自然对数
rand() 随机数
sin(x) 正弦
sqrt(x) 平方根
srand(x) x是rand()函数的种子
int(x) 取整,过程没有舍入
rand() 产生一个大���等于0而小于1的随机数

14.8.4. 自定义函数

在awk中还可自定义函数,格式如下:

function name ( parameter, parameter, parameter, ... ) {
                statements
                return expression                  # the return statement and expression are optional
}

15. How-to

  • 如何把一行竖排的数据转换成横排?

awk '{printf("%s,",$1)}' filename

 

awk中使用NR和FNR的一些例子

http://blog.sina.com.cn/s/blog_5a3640220100b7c8.html

http://www.linuxidc.com/Linux/2012-05/61174.htm

一般在awk里面输入文件是多个时,NR==FNR才有意义,如果这个值为true,表示还在处理第一个文件。

NR==FNR 這個一般用於讀取兩個或者兩個以上的文件中,用於判斷是在讀取第一個文件。。

test.txt  10行内容

test2.txt    4行内容

awk '{print NR,FNR}' test.txt test2.txt
1 1
2 2
3 3
4 4
5 5
6 6
7 7
8 8
9 9
10 10
11 1
12 2
13 3
14 4

 

现在有两个文件格式如下:

#cat account
张三|000001
李四|000002

#cat cdr
000001|10
000001|20
000002|30
000002|15
-----------------------------------------------------------
想要得到的结果是将用户名,帐号和金额在同一行打印出来,如下:
张三|000001|10
张三|000001|20
李四|000002|30
李四|000002|15

执行如下代码

awk -F \| 'NR==FNR{a[$2]=$0;next}{print a[$1]"|"$2}' account cdr

注释:

由NR=FNR为真时,判断当前读入的是第一个文件account,然后使用{a[$2]=$0;next}循环将account文件的每行记录都存入数组a,并使用$2第2个字段作为下标引用.

由NR=FNR为假时,判断当前读入了第二个文件cdr,然后跳过{a[$2]=$0;next},对第二个文件cdr的每一行都无条件执行 {print a[$1]"|"$2},此时变量$1为第二个文件的第一个字段,与读入第一个文件时,采用第一个文件第二个字段$2为数组下标相同.因此可以在此使用 a[$1]引用数组。

awk '{gsub(/\$/,"");gsub(/,/,"");
if ($1>=0.1 && $1<0.2) c1+=1;
else if ($1>=0.2 && $1<0.3) c2+=1;
else if ($1>=0.3 && $1<0.4) c3+=1;
else if ($1>=0.4 && $1<0.5) c4+=1;
else if ($1>=0.5 && $1<0.6) c5+=1;
else if ($1>=0.6 && $1<0.7) c6+=1;
else if ($1>=0.7 && $1<0.8) c7+=1;
else if ($1>=0.8 && $1<0.9) c8+=1;
else if ($1>=0.9 ) c9+=1;
else c10+=1; }
END {printf  "%d\t%d\t%d\t%d\t%d\t%d\t%d\t%d\t%d\t%d\t",c1,c2,c3,c4,c5,c6,c7,c8,c9,c10} ' /NEW

 

示例/例子

awk '{if($0~/^>.*$/) {tmp=$0; getline; if( length($0)>=200) {print  tmp"\n"$0; } }}'  filename

awk '{if($0~/^>.*$/) {IGNORECASE=1; if($0~/PREDICTED/) {getline;} else {print $0; getline;  print $0; } }}' filename

awk '{if($0~/^>.*$/) {IGNORECASE=1; if($0~/mRNA/) {print $0; getline;  print $0; } else {getline;} }}'  filename

awk '{ temp=$0; getline; if($0~/unavailable/) {;} else {print temp"\n"$0;} }' filename

substr($4,20)     --->  表示是从第4个字段里的第20个字符开始,一直到设定的分隔符","结束.

substr($3,12,8)  --->  表示是从第3个字段里的第12个字符开始,截取8个字符结束.

 

一、awk字符串转数字

$ awk 'BEGIN{a="100";b="10test10";print (a+b+0);}' 
110 

#只需要将变量通过”+”连接运算。自动强制将字符串转为整型。非数字变成0,发现第一个非数字字符,后面自动忽略。

 

二、awk列 、行相互转换

将一行内容根据逗号分割为一列

cat filename |awk  -F ',' '{ i = 1; while ( i <= NF ) {print $i; i++}}'

将一列内容根据逗号转换为一行 

awk '{printf "%s,",$1}' filename

 

三、awk数字转为字符串 

$ awk 'BEGIN{a=100;b=100;c=(a""b);print c}'      
100100 

#只需要将变量与””符号连接起来运算即可。

 
四、awk字符串连接操作(字符串连接;链接;串联) 

$ awk 'BEGIN{a="a";b="b";c=(a""b);print c}'      
ab 

$ awk 'BEGIN{a="a";b="b";c=(a+b);print c}'  
0

 把文件中的各行串联起来:

awk 'BEGIN{xxxx="";}{xxxx=(xxxx""$0);}END{print xxxx}' temp.txt
awk 'BEGIN{xxxx="";}{xxxx=(xxxx"\",\""$0);}END{print xxxx}' temp.txt

提取满足条件的子字符串:

 cat > temp
74938 A>G 347589B>C43795743

awk '{x=$0;while (match(x, "[A-Z]>[A-Z]") > 0) {  print substr(x, RSTART, RLENGTH);  x = substr(x, RSTART+RLENGTH);} }' temp

 

五、awk计算百分比和平均值

//计算百分比

 

#计算百分比
success_count=89
interface_count_total=100
awk 'BEGIN{printf "%.8f%\n",'${success_count}'/'${interface_count_total}'*100}'

//计算平均值

cat file
1
2
3
4
#计算平均值
awk '{sum+=$1}END{print sum/NR}' file

#求各行数占总数的百分比:
awk '{a[NR]=$1;sum+=$1}END{for(i=1;i<=NR;i++)printf "%.2f%\n", a[i]*100/sum}' file
10.00%
20.00%
30.00%
40.00%

 

六、awk打印第N列后面的所有列

1、使用awk将文件的前12列替换为空。

awk '{for(i=1;i<=12;i++)$i="";print $0}' localhost_access_log.2015-01-03.txt              //写法一
awk '{for(i=1;i<=12;i++){$i=""};print $0}' localhost_access_log.2015-01-03.txt            //写法二
awk '{for(i=13;i<=NF;i++)printf $i" ";printf "\n"}' localhost_access_log.2015-01-03.txt   //写法三

2、第二步我们就只需要处理每行前面的12个空格即可,假设我们已经将上面的结果重定向到了5201351.txt文件,这时我们再使用sed命令。

[root@5201351 ~]# sed 's/^ *//' 5201351.txt             //这样只能匹配空格开头    
[root@5201351 ~]# sed 's/^\s*//' 5201351.txt            //也可以这样写,除了空格还可以匹配制表符
[root@5201351 ~]# sed 's/^[[:space:]]*//' 5201351.txt   //也可以这样写,除了空格还可以匹配制表符

这样我们就完美的解决了我们的需求,只过滤出日志文件第12列以后所有的内容。

 

七、awk统计文件中某关键词出现次数

1、累加第二列的数值

awk '{a=a+$2}END{print a}'  file

2、若第三列的内容相同,则累加对应记录的第二列数值

awk '{a[$3]+=$2}END{for(i in a) printf "%s\t %d\n",i,a[i]}' file

3、对其他列的内容进行限制筛选以后累加第二列的数值

awk '$4=="abc" && $5>=100 && $6<=500{a=a+$2}END{print a}' file

4、若第三列,第四列内容相同,则累加第二列的数值,并将结果升序输出

awk '{a[$3,"\t",$4]+=$2}END{for(i in a)printf "%s\t %d\n",i,a[i]}' file|sort

5、统计文件test.txt中第2列不同值出现的次数

awk '{sum[$2]+=1}END{for(i in sum)print i"\t"sum[i]}'  test.txt
如文件test.txt第2列的值为"00""01"或"02",执行结果如下:
[root@localhost cc]# cat test.txt
a 00
b 01
c 00
d 02
[root@localhost cc]# awk '{sum[$2]+=1}END{for(i in sum)print i"\t"sum[i]}' test.txt
00 2
01 1
02 1
[root@localhost cc]#

6、如只统计文件test.txt中第2列"00"或"01"出现的次数,命令可写为

[root@localhost cc]# awk '{if($2=="00") ++sum1;if($2=="01") ++sum2}END{print "00""\t"sum1"\n""01""\t"sum2}' test.txt
00 2
01 1

Linux公社的RSS地址https://www.linuxidc.com/rssFeed.aspx

本文永久更新链接地址https://www.linuxidc.com/Linux/2019-08/159735.htm

linux
相关资讯       awk  awk命令  AWK使用  AWK入门 
本文评论   查看全部评论 (0)
表情: 表情 姓名: 字数

       

评论声明
  • 尊重网上道德,遵守中华人民共和国的各项有关法律法规
  • 承担一切因您的行为而直接或间接导致的民事或刑事法律责任
  • 本站管理人员有权保留或删除其管辖留言中的任意内容
  • 本站有权在网站内转载或引用您的评论
  • 参与本评论即表明您已经阅读并接受上述条款